;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; GNU GENERAL PUBLIC LICENSE ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; rl-networks
;; rl-networks is an agent-based model where a population of players
;; embedded in a social network play a 2x2 game using a simple
;; Bush-Mosteller reinforcement learning algorithm
;;
;; Copyright (C) 2009 Anxo Sánchez, Luis R. Izquierdo & José M. Galán
;; 
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License
;; as published by the Free Software Foundation; either version 3
;; of the License, or (at your option) any later version.
;; 
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.
;; 
;; You should have received a copy of the GNU General Public License
;; along with this program; if not, write to the Free Software
;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
;;
;; Contact information:
;; Luis R. Izquierdo 
;;   University of Burgos, Spain. 
;;   e-mail: luis@izquierdo.name


;extensions [array]

;;;;;;;;;;;;;;;;;
;;; VARIABLES ;;;
;;;;;;;;;;;;;;;;;

globals [
  list-of-players
  
  ;; average number of buyers reachable by each buyer
  ;; in an infinite number of steps
  avg-accessibility
  
  clustering-coefficient
]

;;;;;;;;;;;;;;
;;; BREEDS ;;;
;;;;;;;;;;;;;;

breed [players player]

players-own [    
  active?
  my-nbrs
  my-n-of-nbrs
  
  node-clustering-coefficient
  
  nbrs-in-radius-1
  tmp-nbrs
]


;;;;;;;;;;;;;;;;;;;
;;; MODEL SETUP ;;;
;;;;;;;;;;;;;;;;;;;

to startup
  clear-all
  setup-players
  set list-of-players sort players
  build-initial-network
  update-graphs
end

to setup-players
  set-default-shape players "circle"
  create-ordered-players num-players [
    fd 30
    set size 1
  ] 
  ask players [
    set active? ifelse-value 
      (random-float 1.0 < initial-cond-active) 
      [true] [false]
  ]
  
end

;;;;;;;;;;;;;;;;;;;;;;
;;; MAIN PROCEDURE ;;;
;;;;;;;;;;;;;;;;;;;;;;

to go

  let signal ifelse-value (random-float 1.0 <= external-signal) 
    [true] [false]  
  
  ask one-of players [
    if active? != signal [
      let my-active active?
      let fraction-diff-nbrs ((count my-nbrs with [active? != my-active]) / my-n-of-nbrs)
      if fraction-diff-nbrs >= threshold [
        set active? (not active?)
      ]
    ]
  ]
  
  tick
  update-graphs
end


to update-color
  set color ifelse-value active? [blue] [red]
end

  ;; resize-buyers, change back and forth from size based on degree to a size of 1
to resize-players
  ifelse ( not (any? players with [size > 1]) )
  [ ask players [ set size sqrt count my-nbrs] ]
  [ ask players [ set size 1 ] ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; GRAPHS AND DATA GATHERING ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to update-graphs
  ask players [update-color]
  do-plots
end


to plot-accessibility
  let steps accessibility-steps
  if accessibility-steps = "Infinity" [set steps num-players]
  let accessibility-list [accessibility steps] of players 
  let max-accessibility max accessibility-list
  set-current-plot "Accessibility Distribution"
  set-plot-x-range 0 (max-accessibility + 1)  ;; + 1 to make room for the width of the last bar
  histogram accessibility-list
  set avg-accessibility mean accessibility-list
end

to do-plots
  set-current-plot "Active"
  set-current-plot-pen "active"
  plot count players with [active?]
  set-current-plot-pen "inactive"
  plot count players with [not active?]
  
  set-current-plot "Histogram"
  let l [count my-nbrs with [active?]] of (players with [not active?])
  histogram l
  
  set-current-plot "Histogram-2"
  let  ht2 [count my-nbrs with [not active?]] of (players with [ active?])
  histogram  ht2
  
end



;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; NETWORK OPERATIONS ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;

to build-initial-network
  if network-structure = "random"
    [ build-random-network]
  if network-structure = "preferential attachment"
    [ build-preferential-attachment-network pref-attachment-links]
  if network-structure = "double ring"
    [ build-double-ring-network]
  if network-structure = "star"
    [ build-star-network]
  if network-structure = "grid 4 nbrs" or network-structure = "grid 8 nbrs" 
    [ build-grid-network]
  ask players [set my-nbrs link-neighbors set my-n-of-nbrs (count my-nbrs)]
  set num-links count links
  plot-accessibility  
  find-clustering-coefficient
  
end

to build-random-network
   ;; you cannot create more undirected links than (num-players * (num-players - 1) / 2)
 set num-links min list num-links (num-players * (num-players - 1) / 2)
 if-else num-links < (0.72 * (num-players * (num-players - 1) / 2)) 
   [ repeat num-links [add-random-link] ]
   [ 
     ;; make a fully connected network
     let tmp-list-of-players list-of-players
     ;; this creates a list where players are sorted in ascending order by who number
     foreach list-of-players [
       let first-player first tmp-list-of-players
       set tmp-list-of-players but-first tmp-list-of-players
       ask first-player [foreach tmp-list-of-players [create-link-with ?]]
     ]
     
     ;; and randomly delete the necessary links
     ask n-of ((num-players * (num-players - 1) / 2) - num-links) links [die]
   ]
end

to build-preferential-attachment-network [n-of-edges-per-new-vertex]
  ;; This is Barabási and Albert's "preferential attachment" model of network growth (See Newman, 
  ;; "The structure and function of complex networks", sec. 7B). Basically, each new player selects   
  ;; "pref-attachment-links" other players to link to, who are selected with probability proportional to 
  ;; their number of existing links.

  let vertices shuffle sort players
  
  if n-of-edges-per-new-vertex > 0 [
  
  ask (first vertices) [create-link-with (item 1 vertices)]
  let list-of-vertices-repeated list 0 1
  let n-of-vertices-in-the-network 2
  
  repeat (length vertices) - n-of-vertices-in-the-network [
    let vertices-linked []
    while [(length vertices-linked < n-of-edges-per-new-vertex) 
          and (length vertices-linked < n-of-vertices-in-the-network)] [
      let vertex-to-link one-of list-of-vertices-repeated 
      if not member? vertex-to-link vertices-linked [
        set vertices-linked fput vertex-to-link vertices-linked
      ]
    ]
    
    ;; now link the vertices
    ask (item n-of-vertices-in-the-network vertices)
      [foreach vertices-linked [create-link-with item ? vertices]]
   
    ;; and update list-of-vertices-repeated 
    set list-of-vertices-repeated sentence list-of-vertices-repeated vertices-linked
    repeat (length vertices-linked) [
      set list-of-vertices-repeated fput n-of-vertices-in-the-network list-of-vertices-repeated
    ]      
    
    set n-of-vertices-in-the-network (n-of-vertices-in-the-network + 1)
  ]
  
  ]
end

to build-double-ring-network
  ;; seated in a round table and links to the one on the right and the one on the left
  (foreach list-of-players
           (fput last list-of-players but-last list-of-players)
    [ask ?1 [create-link-with ?2]]
  )
  set num-links count links
  plot-accessibility  
end

to build-star-network
  ;; one player is randomly chosen. She links to all the others.
  ask one-of players [create-links-with other players]
end

to build-grid-network
  let players-per-line (ceiling sqrt num-players)
  let gap (min (list world-height world-width)) / players-per-line
  ask players [
    setxy ((who mod players-per-line) * gap + min-pxcor + gap / 2) 
          (int (who / players-per-line) * gap + min-pycor + gap / 2)
  ]
  ask players [
    create-links-with other players 
      in-radius (gap * ifelse-value (network-structure = "grid 4 nbrs") [1.4] [1.8])
    set nbrs-in-radius-1 my-nbrs
  ]
  repeat (grid-radius - 1) [
    ask players [set tmp-nbrs my-nbrs]
    ask players [
      create-links-with other turtle-set ([nbrs-in-radius-1] of tmp-nbrs)
    ]
  ]
end

to add-random-link
  let node-1 one-of players
  let node-2 one-of players
  ask node-1 [
    ifelse link-neighbor? node-2 or node-1 = node-2
    [ add-random-link ]
    [ create-link-with node-2 ]
  ]
end

to-report accessibility [num-steps]
  let step 1
  let reachable-players my-nbrs
  let old-length 0
  let new-length count reachable-players
  while [ new-length != old-length and step < num-steps]
        [ set old-length new-length
          set reachable-players turtle-set
            remove-duplicates sort 
              (turtle-set 
                reachable-players 
                [my-nbrs] of reachable-players) 
          set new-length (count reachable-players)
          set step (step + 1)
        ]
  report new-length - ifelse-value (member? self reachable-players) [1] [0]
end

;; The following two procedures have been copied from the 
;; NetLogo Small Worlds model, in NetLogo's library.
;; Copyright at the end of this page.

to-report in-neighborhood? [ hood ]
  report ( member? end1 hood and member? end2 hood )
end

to find-clustering-coefficient
  ifelse all? players [count my-nbrs <= 1]
  [
    ;; it is undefined
    set clustering-coefficient "undefined"
  ]
  [
    let total 0
    ask players with [ count my-nbrs <= 1]
      [ set node-clustering-coefficient "undefined" ]
    ask players with [ count my-nbrs > 1]
    [
      let hood my-nbrs
      set node-clustering-coefficient (2 * count links with [ in-neighborhood? hood ] /
                                         ((count hood) * (count hood - 1)) )
      ;; find the sum for the value at players
      set total total + node-clustering-coefficient
    ]
    ;; take the average
    set clustering-coefficient total / count players with [count my-nbrs > 1]
  ]
end

;;;;;;;;;;;;;;
;;; Layout ;;;
;;;;;;;;;;;;;;

to do-layout
  ;; the number 3 here is arbitrary; more repetitions slows down the
  ;; model, but too few gives poor layouts
  repeat 3 [
    ;; the more players we have to fit into the same amount of space,
    ;; the smaller the inputs to layout-spring we'll need to use
    let factor sqrt count players
    ;; numbers here are arbitrarily chosen for pleasing appearance
    layout-spring (players with [any? my-nbrs]) links (1 / factor) (7 / factor) (3 / factor)
    display  ;; for smooth animation
  ]
  ;; don't bump the edges of the world
  let x-offset max [xcor] of players + min [xcor] of players
  let y-offset max [ycor] of players + min [ycor] of players
  ;; big jumps look funny, so only adjust a little each time
  set x-offset limit-magnitude x-offset 0.1
  set y-offset limit-magnitude y-offset 0.1
  ask players [ setxy (xcor - x-offset / 2) (ycor - y-offset / 2) ]
end

to-report limit-magnitude [number limit]
  if number > limit [ report limit ]
  if number < (- limit) [ report (- limit) ]
  report number
end

; *** NetLogo 4.0.4 Model Copyright Notice ***
;
; Copyright 2005 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2005).  NetLogo Small Worlds model.
; http://ccl.northwestern.edu/netlogo/models/SmallWorlds.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2005 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/SmallWorlds
; for terms of use.
;
; *** End of NetLogo 4.0.4 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
232
10
747
546
50
50
5.0
1
10
1
1
1
0
1
1
1
-50
50
-50
50
1
1
1
time

CC-WINDOW
5
717
974
812
Command Center
0

CHOOSER
9
539
212
584
network-structure
network-structure
"random" "preferential attachment" "double ring" "star" "grid 4 nbrs" "grid 8 nbrs"
4

SLIDER
8
629
202
662
pref-attachment-links
pref-attachment-links
0
100
1
1
1
NIL
HORIZONTAL

SLIDER
9
592
181
625
num-links
num-links
0
10000
800
1
1
NIL
HORIZONTAL

BUTTON
5
10
72
43
setup
startup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
76
10
139
43
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
144
10
227
43
go once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
4
73
227
106
num-players
num-players
0
1600
400
1
1
NIL
HORIZONTAL

PLOT
234
553
480
703
Accessibility Distribution
# of reachable players
# of players
0.0
2.0
0.0
10.0
true
false
PENS
"default" 1.0 1 -16777216 false

CHOOSER
488
559
630
604
accessibility-steps
accessibility-steps
1 2 3 4 5 10 20 "Infinity"
5

BUTTON
488
608
631
641
Update accessibility
plot-accessibility
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
634
551
745
604
NIL
avg-accessibility
3
1
13

BUTTON
618
661
739
694
relax network
do-layout
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
491
661
615
694
NIL
resize-players
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
3
153
228
186
external-signal
external-signal
0
1
0.6
0.01
1
NIL
HORIZONTAL

SLIDER
9
666
181
699
grid-radius
grid-radius
1
10
1
1
1
NIL
HORIZONTAL

MONITOR
635
606
744
659
clust. coeff.
clustering-coefficient
3
1
13

SLIDER
4
112
230
145
threshold
threshold
0
1
0.441
0.001
1
NIL
HORIZONTAL

SLIDER
3
186
228
219
initial-cond-active
initial-cond-active
0
1
0.6
0.01
1
NIL
HORIZONTAL

PLOT
758
37
958
187
Active
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"active" 1.0 0 -13345367 true
"inactive" 1.0 0 -2674135 true

PLOT
765
260
965
410
Histogram
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"default" 1.0 1 -16777216 true

PLOT
765
418
965
568
Histogram-2
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"default" 1.0 1 -2674135 true

@#$#@#$#@
WHAT IS IT?
-----------
This section could give a general understanding of what the model is trying to show or explain.


HOW IT WORKS
------------
This section could explain what rules the agents use to create the overall behavior of the model.


HOW TO USE IT
-------------
This section could explain how to use the model, including a description of each of the items in the interface tab.


THINGS TO NOTICE
----------------
This section could give some ideas of things for the user to notice while running the model.


THINGS TO TRY
-------------
This section could give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.


EXTENDING THE MODEL
-------------------
This section could give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.


NETLOGO FEATURES
----------------
This section could point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.


RELATED MODELS
--------------
This section could give the names of models in the NetLogo Models Library or elsewhere which are of related interest.


CREDITS AND REFERENCES
----------------------
This section could contain a reference to the model's URL on the web if it has one, as well as any other necessary credits or references.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@